Problem Description


If you have Cloud Drive Mapper only and you have multiple classifications, you may experience an issue where it loads only with the first classification.



Solution


Remove the default Cloud Drive Mapper and add a script.



Solution Details


To get around this, you will need to remove the default Cloud Drive Mapper from startup and then add the following script to startup on user login via Group Policy (Adding startup scripts to group policy is out of the scope of this document).


An attachment is available with the code as an editable batch file if you experience issues copying and pasting.


@echo off

taskkill /im "Cloud Drive Mapper.exe" /F

setlocal enabledelayedexpansion

for /f "tokens=*" %%i in ('whoami /groups') do set GROUPS=!GROUPS!;%%i

 

rem SET LICENSE KEY HERE AND PATH

set CDMLICENSEKEY=[license key]

set CDMPATH="C:\Program Files\IAM Cloud\Cloud Drive Mapper\"

 

rem SET GROUP NAMES AND CLASSIFICATIONS HERE

rem eg. for 2 groups

rem 1. called 'IAMCLOUD\AllStaff' which should get classification number 12345

rem 2. called 'IAMCLOUD\Support' which should get classification number 23456

rem the syntax of the command should be as follows:

call:checkcdmgroup "IAMCLOUD\AllStaff", 12345

call:checkcdmgroup "IAMCLOUD\Support", 23456

if "%CLASSIFICATIONID%"=="" (

echo not classified

) else (

CD %CDMPATH%

start "" "Cloud Drive Mapper.exe" -l %CDMLICENSEKEY% -c %CLASSIFICATIONID%

)

 

goto :eof

:checkcdmgroup

echo %groups%|findstr /lic:"%~1" >nul && set CLASSIFICATIONID=%~2


This will detect the group which a user is in and then start up Cloud Drive Mapper with that classification.


Please note: if you have a user who is in multiple classified groups, it will only get the last classification.


eg.

 

Bob is a member of IAMCLOUD\AllStaff

Alice is a member of IAMCLOUD\Support

Eve is a member of both IAMCLOUD\AllStaff and IAMCLOUD\Support

Eve would get logged in with IAMCLOUD\Support(classificationID 23456)